|
New to Ham Radio?
My Profile
Community
Articles
Forums
News
Reviews
Friends Remembered
Speak Out
Strays
Survey Question
Operating
Contesting
DX Cluster Spots
Propagation
Resources
Calendar
Classifieds
Ham Exams
Ham Links
List Archives
News Articles
Product Reviews
QSL Managers
Site Info
eHam Help (FAQ)
Support the site
The eHam Team
Advertising Info
Vision Statement
About eHam.net
|
|
1-2 of 2 messages
|
Page 1 of 1
|
|
Critique this circuit
|
Reply
|
|
by AG4DG on August 20, 2002
|
Mail this to a friend!
|
Here is the PSPICE code. The comments explain my design.
The circuit works in PSPICE. Is there any practical reason it would NOT work? Do you have any ideas for a better design?
ELF MONITOR
.PROBE V(13), V(14)
.PARAM amplitude={A10}
.PARAM frequency=60Hz
.PARAM A0=.9765625uv, A1=1.953125uv, A2=3.90625uv, A3=7.8125uv, A4=15.625uv, A5=31.25uv,
.PARAM A6=62.5uv, A7=125uv, A8=250uv, A9=500uv, A10=1mv, A11=2mv
.TRAN 1s 5s UIC
* This is an ELF monitoring circuit.
* The analog input consists of a small ELF current (around 60 Hz) between 2uV and 1mV.
* This voltage is processed by three amplifiers and a rectifier.
* The analog output voltage is a logarithmic function of the analog input and is in the range of 3
* to 5 V DC.
* This analog output voltage is fed into a voltage divider and then fed into an LM3914 IC chip for
* an LED display.
* The input voltage consists of a Radio Shack telephone pickup coil (part 44-533).
* This coil produces an AC voltage in response to a magnetic field.
* Placing this magnetic detector within a few inches from a strong ELF field source (such as a TV or
* fluorescent light) produces a voltage of 1mV or greater.
* Moving the pickup coil further away rapidly reduces its voltage.
* Simply moving the pickup coil a few feet away from the ELF source reduces the voltage to less
* than .1mV.
* The output of the circuit consists of ten LEDs connected to an LM3914 IC chip.
* If the LM3914's input voltage exceeds a certain threshold, its respective LED will light up.
* The circuit is designed so that a 1mV or greater pickup coil voltage lights up the 10th LED.
* For each 3dB (or factor of 2) below this level, the previous LED lights up.
* If the pickup coil voltage is between .5mV and 1mV, the 9th LED will light.
* If the pickup coil voltage is below about 2uV, then none of the 10 LEDs will light.
* Input voltage threshold -> LED lit
* A0=.9765625uv->3dB below low threshold
* A1=1.953125uv->LED1
* A2=3.90625uv-->LED2
* A3=7.8125uv--->LED3
* A4=15.625uv--->LED4
* A5=31.25uv---->LED5
* A6=62.5uv----->LED6
* A7=125uv------>LED7
* A8=250uv------>LED8
* A9=500uv------>LED9
* A10=1mv------->LED10
* A11=2mv------->3dB above high threshold
* Two power supplies are needed to power the amplifiers.
* If only one power supply is provided, then half of the waveform will not be amplified.
* Providing only the first battery would give the amplifiers only a 0V to +9V range.
* Providing only the second battery would give the amplifiers only a -9V to 0V range.
* Using both batteries provides the full -9V to +9V range.
Vbattery1 1 0 DC 9
Vbattery2 0 2 DC 9
* This is the voltage from the pickup coil.
Vin 3 0 SIN (0V {amplitude} {frequency} 2s 0Hz 0d)
* The pickup coil has 276.3 ohms of resistance.
Rin 3 4 276.3
* STAGE 1 AMPLIFIER
* This amplifier provides a gain of about 368 (R2/(R1+Rin)), or about 25.7dB.
* It is also used as a high pass active filter.
* Op amps have DC offset voltages that can sometimes dwarf the input voltage, especially if the
* input voltage is tiny.
* The values of Rin, R1, and C1 determine the cutoff frequency.
* With resistor R1 at 1K ohms and capacitor C1 at 22uF, the cutoff frequency is 5.67Hz.
* Also note that a TL082 amplifier is used for two reasons.
* First, the TL082 amplifier's DC offset voltage is low enough to be manageable for our input
* voltage values.
* Second, the TL082 IC is available at Radio Shack.
R1 4 5 1K
C1 5 6 22UF
X1 0 6 1 2 7 TL082
R2 6 7 470K
* Voltage threshold -> 0-peak stage 1 output voltage
* A0----->.335mv
* A1----->.695mv
* A2---->1.41 mv
* A3---->2.84 mv
* A4---->5.70 mv
* A5--->11.4 mv
* A6--->22.9 mv
* A7--->45.7 mv
* A8--->91.5 mv
* A9-->183 mv
* A10->365 mv
* A11->730 mv
* STAGE 2 AMPLIFIER
* This amplifier is a logarithmic amplifier.
* The gain is much greater for low input voltages than is the case with high input voltages.
* Each dB of input voltage difference becomes a fixed output voltage difference (18mV).
* Because the TL082 chip has two amplifiers, and our input AC signal still may be weak, we
* use another TL082 amplifier.
* Capacitor C2 is provided to make this amplifier a high pass amplifier that rejects the
* DC offset voltage.
* Because of R3 and C2, the cutoff frequency is 5.89Hz.
* Logarithmic amplifier reference: http://www.play-hookey.com/analog/logarithmic_amplifier.html
R3 7 8 270K
C2 8 9 .1UF
X2 0 9 1 2 10 TL082
Q1 9 0 10 Q2N2222
Q2 9 0 10 Q2N2907A
* Voltage threshold -> 0-peak stage 2 input voltage -> 0-peak stage 2 output voltage -> Gain ->
* dB gain
* A0----->.335mv->375mv->1120---->+30.5dB
* A1----->.695mv->393mv-->565---->+27.5dB
* A2---->1.41 mv->411mv-->291---->+24.6dB
* A3---->2.84 mv->429mv-->151---->+21.8dB
* A4---->5.70 mv->447mv--->78.4-->+18.9dB
* A5--->11.4 mv->465mv--->40.8-->+16.1dB
* A6--->22.9 mv->483mv--->21.1-->+13.2dB
* A7--->45.7 mv->501mv--->11.0-->+10.4dB
* A8--->91.5 mv->519mv---->5.67-->+7.5dB
* A9-->183 mv->537mv---->2.93-->+4.7dB
* A10->365 mv->555mv---->1.52-->+1.8dB
* A11->730 mv->573mv----->.785->-1.1dB
* STAGE 3 AMPLIFIER
* The logarithmic amplifier provides us with 393 to 573 mV of input for this amplifier.
* Another IC is needed, because the both op amps in the TL082 chip are occupied by the two previous
* amplifiers.
* I have selected a 741 amplifier for the third stage.
* The DC offset voltage is much less of a concern now due to our much larger input voltage here.
* Although another TL082 amplifier would work here, a 741 meets our needs, is also available from
* Radio Shack, and is cheaper.
* The gain of this amplifier is 10 (R5/R4), or 10dB.
* C3 turns this amplifier into a high pass active filter and combines with R4 to provide a cutoff
* frequency of 5.89Hz.
R4 10 11 1K
C3 11 12 27UF
X3 0 12 1 2 13 uA741
R5 12 13 10K
* Voltage threshold -> 0-peak stage 3 output voltage
* A0-->3.54V
* A1-->3.74V
* A2-->3.92V
* A3-->4.10V
* A4-->4.32V
* A5-->4.49V
* A6-->4.70V
* A7-->4.89V
* A8-->5.08V
* A9-->5.29V
* A10->5.48V
* A11->5.68V
* RECTIFICATION
* The 1N4148 rectifies the signal.
* Our 60Hz AC voltage is transformed into a DC voltage.
* R6 and D1 form a voltage divider.
* A high value of R6 maximizes V(14).
* R6 and C4 form a low pass filter.
* This time, we want to pass the DC voltage and reject the fluctuations.
* Thus, C4 is used as a coupling capacitor.
* R6 and C4 give us a cutoff frequency of 15.9Hz.
* V(14) is the analog output voltage fed into the LM3914 chip.
D1 13 14 D1N4148
R6 14 0 10MEG
C4 14 0 .1UF
* Voltage threshold -> DC output of rectifier
* A0-->3.0 to 3.1V
* A1-->3.2 to 3.3V
* A2-->3.4 to 3.5V
* A3-->3.55 to 3.65V
* A4-->3.75 to 3.85V
* A5-->
* A6-->
* A7-->
* A8-->
* A9-->
* A10->4.95 to 5.0V
* A11->5.1 to 5.2V
* NEXT STAGE: VOLTAGE DIVIDER
* The voltage divider will attenuate the DC voltage so that there is just a 1.25V differential
* between the DC voltage associated with the A1 threshold and the DC voltage associated with the A10
* threshold.
* FINAL STAGE: LM3914
* The LM3914 IC will be configured so that the low voltage threshold corresponds to the LM3914
* input associated with the A1 threshold, and the high voltage threshold corresponds to the LM3914
* input associated with the A10 threshold. These thresholds are 1.25V apart.
* DOT MODE:
* If the voltage is below the A1 threshold, none of the 10 LEDs connected to the LM3914 will light.
* If the voltage is above the A10 threshold, the last LED will light. For voltages between the A1
* and A10 thresholds, one of the other nine LEDs will light.
* BAR MODE:
* The LM3914 also has a bar mode configuration. If one LED lights, all of the LEDs representing
* lower voltage levels will also light up.
.MODEL D1N4148 D (IS=0.1PA, RS=16 CJO=2PF TT=12N BV=100 IBV=0.1PA)
.model Q2N2222 NPN(Is=14.34f Xti=3 Eg=1.11 Vaf=74.03 Bf=255.9 Ne=1.307
+ Ise=14.34f Ikf=.2847 Xtb=1.5 Br=6.092 Nc=2 Isc=0 Ikr=0 Rc=1
+ Cjc=7.306p Mjc=.3416 Vjc=.75 Fc=.5 Cje=22.01p Mje=.377 Vje=.75
+ Tr=46.91n Tf=411.1p Itf=.6 Vtf=1.7 Xtf=3 Rb=10)
* National pid=19 case=TO18
* 88-09-07 bam creation
.model Q2N2907A PNP(Is=650.6E-18 Xti=3 Eg=1.11 Vaf=115.7 Bf=231.7 Ne=1.829
+ Ise=54.81f Ikf=1.079 Xtb=1.5 Br=3.563 Nc=2 Isc=0 Ikr=0 Rc=.715
+ Cjc=14.76p Mjc=.5383 Vjc=.75 Fc=.5 Cje=19.82p Mje=.3357 Vje=.75
+ Tr=111.3n Tf=603.7p Itf=.65 Vtf=5 Xtf=1.7 Rb=10)
* National pid=63 case=TO18
* 88-09-09 bam creation
* TL082 subcircuit code from
* http://www.macs.ece.mcgill.ca/~roberts/COURSES/EE334/SPICE_MODEL_LIB.html
* connections: non-inverting input
* | inverting input
* | | positive power supply
* | | | negative power supply
* | | | | output
* | | | | |
.subckt TL082 1 2 3 4 5
c1 11 12 2.412E-12
c2 6 7 18.00E-12
css 10 99 5.400E-12
dc 5 53 dx
de 54 5 dx
dlp 90 91 dx
dln 92 90 dx
dp 4 3 dx
egnd 99 0 poly(2),(3,0),(4,0) 0 .5 .5
fb 7 99 poly(5) vb vc ve vlp vln 0 3.467E6 -3E6 3E6 3E6 -3E6
ga 6 0 11 12 339.3E-6
gcm 0 6 10 99 17.01E-9
iss 10 4 dc 234.0E-6
hlim 90 0 vlim 1K
j1 11 2 10 jx
j2 12 1 10 jx
r2 6 9 100.0E3
rd1 3 11 2.947E3
rd2 3 12 2.947E3
ro1 8 5 50
ro2 7 99 170
rp 3 4 20.00E3
rss 10 99 854.7E3
vb 9 0 dc 0
vc 3 53 dc 1.500
ve 54 4 dc 1.500
vlim 7 8 dc 0
vlp 91 0 dc 50
vln 0 92 dc 50
.model dx D(Is=800.0E-18 Rs=1)
.model jx NJF(Is=2.500E-12 Beta=984.2E-6 Vto=-1)
.ends
*$
*-----------------------------------------------------------------------------
* connections: non-inverting input
* | inverting input
* | | positive power supply
* | | | negative power supply
* | | | | output
* | | | | |
.subckt uA741 1 2 3 4 5
*
c1 11 12 8.661E-12
c2 6 7 30.00E-12
dc 5 53 dx
de 54 5 dx
dlp 90 91 dx
dln 92 90 dx
dp 4 3 dx
egnd 99 0 poly(2) (3,0) (4,0) 0 .5 .5
fb 7 99 poly(5) vb vc ve vlp vln 0 10.61E6 -10E6 10E6 10E6 -10E6
ga 6 0 11 12 188.5E-6
gcm 0 6 10 99 5.961E-9
iee 10 4 dc 15.16E-6
hlim 90 0 vlim 1K
q1 11 2 13 qx
q2 12 1 14 qx
r2 6 9 100.0E3
rc1 3 11 5.305E3
rc2 3 12 5.305E3
re1 13 10 1.836E3
re2 14 10 1.836E3
ree 10 99 13.19E6
ro1 8 5 50
ro2 7 99 100
rp 3 4 18.16E3
vb 9 0 dc 0
vc 3 53 dc 1
ve 54 4 dc 1
vlim 7 8 dc 0
vlp 91 0 dc 40
vln 0 92 dc 40
.model dx D(Is=800.0E-18 Rs=1)
.model qx NPN(Is=800.0E-18 Bf=93.75)
.ends
.END
|
| |
|
RE: Critique this circuit
|
Reply
|
|
by VK2GWK on August 27, 2002
|
Mail this to a friend!
|
Sorry, but I cannot reproduce this in any way. Therefor my comments are of a general nature....
IMHO it will not work as you are using very small voltages and amplify them without eliminating the surrounding "pollution". Apart from the "noise" produced by the object you want to measure there will be a lot of other electro magnetic radiation in the environment that your pick up coil will pick up as well.....
You would want to look at "instrumentation amplifiers" that may provide the solution.
|
| |
|
Email Subscription
You are not subscribed to this topic.
Subscribe!
My Subscriptions
Subscriptions Help
Check our help page for help using
Forum, or send questions, comments, or suggestions to the
Forum Manager.
|
|
|
